Formulario de contacto

Nombre

Correo electrónico *

Mensaje *

viernes, 27 de marzo de 2015

Usos prácticos de la función SUMAPRODUCTO?

SUMAPRODUCTO es una de esas funciones en Excel que merece la pena entender bien porque puede facilitar mucho las cosas.


Sintaxis y uso:


Vayamos primero a ver su sintaxis:


SUMAPRODUCTO(matriz1, [matriz2], …)


  • matriz1 (Obligatorio): Primera matriz que se desea multiplicar y después sumar.

  • matriz2 (Opcional): Segunda matriz que se desea multiplicar y después sumar.



En realidad, esta función son dos funciones en una ya que nos permite realizar la multiplicación de los valores pertenecientes a las matrices proporcionadas para obtener su producto y posteriormente realiza la suma de todos esos productos.

Conviene mencionar que las matrices que se proporcionan como argumentos deben tener las mismas dimensiones o de lo contrario la función SUMAPRODUCTO devolverá el error #¡VALOR!.


Por ejemplo, digamos que tenemos las siguientes 2 matrices:


Sumaproducto


Matriz1:  A1:A3 = {2,10,-1}, matriz de 3 filas por 1 columna (3x1)


Matriz 2: B1:B3 = {4,1.5,3}, matriz de 3 filas por 1 columna (3x1)


Ahora vemos qué hace esta función.


=SUMAPRODUCTO(A1:A3,B1:B3) = {2*4+10*1.5+(-1)*3}= 20


Asi que lo que ha hecho es multiplicar A1 por B1, A2 por B2 y A3 por B3 y luego a sumado esos resultados.


Y ahora te preguntarás, y ésto para qué me sirve? Sigue leyendo y veremos si al final de este post sigues pensando igual.



Ejemplos muy útiles de cómo usar SUMAPRODUCTO:


Ejemplo 1: Sumar/contar los valores en una tabla con 2 condiciones


Imaginemos que tenemos una tabla en A1:C17, con tres columnas para país, tipo y valor. Algo así:


Tabla


Ahora imaginemos que queremos calcular la suma de los valores de Uruguay, con un tipo D. Es decir, que queremos la suma de la columna Valor, pero con 2 condiciones dadas, una que el país sea Uruguay y la otra que el tipo sea D.


Y por qué no usar SUMAPRODUCTO para ésto?


=SUMAPRODUCTO(--((A1:A17)="Uruguay"),--((B1:B17)="D"),C1:C17) = 16


Y ésto qué es!!?? Me voy...


No No!! Quédate, que te lo voy a explicar...


Ya verás, vamos a dividirlo por partes y veremos cómo funciona ésto.


La primera matriz es: --((A1:A17)="Uruguay"), y ésta lo que hace es buscar Uruguay en el rango A1:A17. Esta fórmula a solas sería una fórmula de matriz. Si se pone =(A1:A17)="Uruguay" en una celda, y se pulsa ENTRAR. Ahora sobre la misma celsa, pulsa F2 y F9. Verás cómo se ha calculado la matriz.


=(A1:A17)="Uruguay" = (después de pulsar F2 + F9) ={FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;VERDADERO;VERDADERO;FALSO;FALSO;FALSO;VERDADERO}


Ahora si se pone "--" delante de la fórmula, se cambian los FALSO/VERDADEROS por 0/1s.


=--((A1:A17)="Uruguay") = (después de pulsar F2 + F9) = {0;0;1;0;0;0;0;0;0;0;0;1;1;0;0;0;1}


La seguna matriz sigue el principio que acabamos de mencionar, pero esta vez busca en el rango B1:B17 aquellas celdas que son iguales a D.


=--((B1:B17)="D") = (después de pulsar F2 + F9) = {0;0;0;0;1;0;0;0;1;0;0;0;1;0;0;0;1}


Uniendo las 2 matrices con sus condiciones nos queda que estamos buscando sólo a aquellas filas que tengan a Uruguay por país y a D por el tipo.


Filtrada


La tercera matriz simplemente es la matriz C1:C17 = {"Valor";4;4;5;10;2;5;10;10;4;1;7;7;6;10;9;9}


Así que ahora vemos el producto de las 3 matrices, todas ellas con las mismas dimensiones, 17 filas por 1 columna (17x1).


Matriz 1 = {0;0;1;0;0;0;0;0;0;0;0;1;1;0;0;0;1}


Matriz 2 = {0;0;0;0;1;0;0;0;1;0;0;0;1;0;0;0;1}


Matriz 3 = {"Valor";4;4;5;10;2;5;10;10;4;1;7;7;6;10;9;9}


La función SUMAPRODUCTO multiplica el primer valor de la matriz 1 por el primero de la matriz 2 por el primero de la matriz 3 + el segundo valor de la matriz 1 por el segundo de la matriz 2 por el segundo de la matriz 3 + ....+ el último valor de la matriz 1 por el último de la matriz 2 por el último de la matriz 3.


=SUMAPRODUCTO(--((A1:A17)="Uruguay"),--((B1:B17)="D"),C1:C17)={0*0*"Valor"+0*0*4+1*0*4+0*0*5+0*1*10+0*0*2+0*0*5+0*0*10+0*1*10+0*0*4+0*0*1+1*0*7+1*1*7+0*0*6+0*0*10+0*0*9+1*1*9}=16


Con lo que, como acabamos de ver, es una manera de hacer operaciones (sumar, contar, etc) en una columna con unas condiciones dadas en las otras columnas.


Si, por ejemplo, eliminamos el C1:C17 de la fórmula anterior, lo que hacemos es contar el número de ocurrencias en el que las condiciones de cumplen.


=SUMAPRODUCTO(--((A1:A17)="Uruguay"),--((B1:B17)="D"))=2



------------------------------------------------------------------------------------------------------------------------

RECUERDA QUE:

Tú puedes colaborar para seguir manteniendo este blog de una manera gratuita haciendo varios clics en los anuncios de la página. Como referencia, 2 clics por artículo. Muchas gracias por querer colaborar.

------------------------------------------------------------------------------------------------------------------------

Ejemplo 2: Buscar un valor en un rango de 2 dimensiones con 2 condiciones


Ahora tenemos un rango de 2 dimensiones en Excel. Algo así:


Buscar rango


Y queremos obtener el número de unidades de España con un tipo B. Pues también podemos usar SUMAPRODUCTO para ello. Que cómo?  Pues así.


=SUMAPRODUCTO(($B$4:$B$9="España")*($C$3:$F$3="B")*($C$4:$F$9)) = 6


Esta fórmula funcionaría más o menos de la misma manera que anteriormente. Estamos multiplicando 3 matrices.


Matriz 1 = ($B$4:$B$9="España"), matriz de 6 filas x 1 columna (6x1)


Matriz 2 = ($C$3:$F$3="B"), matriz de 1 fila x 4 columnas (1x4)


Matriz 3 = ($C$4:$F$9), matriz de 6 filas x 4 columnas (6x4)


Multiplicando matriz 1 x matriz 2 (6x1  x  1x4) obtenemos una matriz de 6 filas y 4 columnas, que se puede multiplicar a la matriz 3 ya que tiene el mismo número de filas y de columnas.



Ejemplo 3: Sumar/contar valores en un rango de 2 dimensiones con condiciones múltiples 


Seguimos teniendo el rango del ejemplo 2.


Ahora no sólo queremos 1 país sino 2 a la vez, y más de un tipo también. Digamos que queremos la suma de valores de India & Islandia, y del tipo A y C. Pues también podemos usar la función SUMAPRODUCTO.


=SUMAPRODUCTO((($B$4:$B$9=$E$19)+($B$4:$B$9=$F$19))*(($C$3:$F$3=$E$20)+($C$3:$F$3=$F$20))*($C$4:$F$9)) = 27


Como antes, es la multiplicación de 3 matrices de la misma dimensión que antes. La diferencia es que ahora tanto la matriz 1 como la 2 son la suma de otras 2 matrices. La matriz 1 es la suma de dos matrices de 6 filas con 1 columna, por lo tanto el resultado es una matriz de 6 filas con 1 columna. Lo mismo le pasa a la matriz 2 pero esta vez con 1 fila con 4 columnas.


Para sólo contar el número de ocurrencias, quitamos ($C$4:$F$9) de la fórmula.


=SUMAPRODUCTO((($B$4:$B$9=$E$19)+($B$4:$B$9=$F$19))*(($C$3:$F$3=$E$20)+($C$3:$F$3=$F$20))) = 4.


Bueno, qué tal fue el viaje? Acabamos de ver que la función SUMAPRODUCTO puede ser muy pero que muy útil. Sólo he puesto alguno de los usos útiles, pero habrá mas. Si te apetece compartir cómo usas esta función dejamos un comentario.




Enlace relacionado



Las fórmulas de matriz
La función SUMAPRODUCTO



Te ha gustado el artículo?


No te olvides de mostrar tu gratitud hacia el autor (yo) mediante una de las 3 siguientes acciones:

1. Puedes dejar una donación pinchando en la siguiente imagen.


PayPal. La forma rápida y segura de pagar en Internet


2. Puedes hacer clic en los anuncios mostrados en la página

3. Puedes recomendar el artículo en Google haciendo clic en g+1 (justo después del artículo), también puedes compartirlo en Facebook, y/o dejar comentarios.

Quieres aprender más en Excel o tienes algún problema que necesita solución?

Puedo ofrecer servicios de consultoría así como cursos personalizados online. Mírate el siguiente enlace si estás interesado/a.

Descargarse el archivo


Para descargarse el archivo con el ejemplo ve al siguiente enlace.



Subscríbete y recibe todos las entradas por email


Para ello regístrate suministrando tu email en el sitio "Recibe los trucos en tu email" del menú de la derecha.

O sígueme por las redes sociales


No hay comentarios:

Publicar un comentario